//===== eAthena Script =======================================
//= Card Remover
//===== By: =========================
//= Kutt Katrea (kg.designer@gmail.com)
//= Basado en "Card removal NPC by TyrNemesis"
//===== Current Version: ===================
//= 1.1
//===== Compatible With: =====================
//= eAthena SVN
//===== Description: ============================================
//= Un removedor de cartas.
//= Pone un NPC en prontera que da informes sobre el removedor.
//= El removedor es temperamental, y si lo hacen enojar baja la
//= probabilidad de éxito a con ese personaje.
//= El removedor solo puede salvar una cosa: el arma o las cartas,
//= pero nunca ambas.
//===== Additional Comments: ==========================================
//= [20-Julio-2007] V1.0 Primer lanzamiento.
//= [22-Julio-2007] V1.1 Corrección de los nombres mostrados
//=====================================================================

//Informes
prontera.gat,145,232,5	script	Estudiante Removedor::remover_student	914,{
set @npc_name$,"^FF0000[Estudiante Removedor de Cartas]^000000";
mes @npc_name$;
mes "Estudio el arte de sacar cartas de los equipos.";
mes "Pero siempre termino rompiendo cartas y equipo.";
next;
mes @npc_name$;
mes "Escuche de un Deviruchi que fue criado por Orcos que ha aprendido el arte de separar cartas y equipo";
next;
mes @npc_name$;
mes "Tal vez aún viva en la Villa de los Orcos.";
close;
}

//Removedor
in_orcs01.gat,97,178,7	script	Carter::card_remover	738,{
set @npc_name$,"^FF0000[Carter]^000000";
if (card_remover_aproval==1) goto	Lnoaproval;
if (card_remover_aproval==2) goto   Laproval;
mes @npc_name$;
mes	"¡Todos me detestaban por ser diferente a los demás orcos, pero ahora que aprendi un gran arte me respetan mas que a cualquiera en la aldea!";
next;

menu
	"Tu no eres un orco...", Lnoorc,
	"¿Que arte?",-;

mes @npc_name$;
mes "Pues, aprendi el arte de limpiar armas de esas molestas cartas";
mes "Y de destruir las armas sin dañar las cartas";
next;

mes @npc_name$;
mes "Me has caido bien";
mes "¿Quieres que haga algo por tí?";
set	card_remover_aproval,2;
next;
goto Laproval;

Lnoorc:
mes @npc_name$;
mes	"¡Como te atreves a negar que YO sea un Orco!";
mes	"¡Ahora nunca te enseñare mi arte!";
set card_remover_aproval,1;
close;

Lnoaproval:
mes @npc_name$;
mes "¡Tú me ofendiste!";
next;
emotion e_dots; 

mes @npc_name$;
mes "Esta bien, te ayudaré...";
mes "¡Pero que quede claro que NO me agradas!";
next;

Laproval:
mes @npc_name$;
mes "Puedo remover cartas de tu equipo";
mes "¡Pero recuerda que solo salvarás una cosa, o cartas o equipo!";
next;

REMOVEMENU:
	mes @npc_name$;
	mes "Bien, ¿que equipo quieres que revise?";
	next;
	menu "Ninguno",Lninguno,
	     getequipname(1),SLOT1,
	     getequipname(2),SLOT2,
	     getequipname(3),SLOT3,
	     getequipname(4),SLOT4,
	     getequipname(5),SLOT5,
	     getequipname(6),SLOT6,
	     getequipname(7),SLOT7,
	     getequipname(8),SLOT8,
	     getequipname(9),SLOT9,
	     getequipname(10),SLOT10;

SLOT1:
	set @part,1;
	goto CARDNUMCHECK;

SLOT2:
	set @part,2;
	goto CARDNUMCHECK;

SLOT3:
	set @part,3;
	goto CARDNUMCHECK;

SLOT4:
	set @part,4;
	goto CARDNUMCHECK;

SLOT5:
	set @part,5;
	goto CARDNUMCHECK;

SLOT6:
	set @part,6;
	goto CARDNUMCHECK;

SLOT7:
	set @part,7;
	goto CARDNUMCHECK;

SLOT8:
	set @part,8;
	goto CARDNUMCHECK;

SLOT9:
	set @part,9;
	goto CARDNUMCHECK;

SLOT10:
	set @part,10;
	goto CARDNUMCHECK;

CARDNUMCHECK:
	if(getequipcardcnt(@part) == 0) goto DENYCARDCOUNT;
	set @cardcount,getequipcardcnt(@part);
	if(@cardcount > 1) goto CARDNUMMULTIMSG;
	mes @npc_name$;
	mes "Este equipo tiene " + @cardcount + " carta. ";
	goto CARDNUMPOSTMSG;
CARDNUMMULTIMSG:
	mes @npc_name$;
	mes "Este equipo tiene " + @cardcount + " cartas.";
CARDNUMPOSTMSG:
	next;
	menu "Bien, adelante.",REMOVECARDWARNING,
	     "Mejor no.",Lninguno;

REMOVECARDWARNING:
	mes @npc_name$;
	mes "Antes de empezar, debo recordarte que solo puedo salvar o las cartas o el equipo; y que si fallo se destruyen ambas. ¿Asi que dime, que quieres recuperar?";
	next;
	menu "Mejor ya no.",Lninguno,
	     "El equipo.",PRIORITYITEM,
	     "Las cartas.",PRIORITYCARD;

PRIORITYITEM:
	set @failtype,1;
	goto REMOVECARD;

PRIORITYCARD:
	set @failtype,2;
	goto REMOVECARD;

REMOVECARD:
	mes @npc_name$;
	mes "Bien, empezaré";

	set @failchance,rand(100);
if (card_remover_aproval==1) goto	Lchancenoaproval;
	if(@failchance < 30) goto FAILREMOVECARD0;
	if(@failchance < 60) goto FAILREMOVECARD3;
	if(@failtype == 1) goto FAILREMOVECARD1;
	if(@failtype == 2) goto FAILREMOVECARD2;

Lchancenoaproval:
	if(@failchance < 40) goto FAILREMOVECARD0;
	if(@failchance < 80) goto FAILREMOVECARD3;
	if(@failtype == 1) goto FAILREMOVECARD1;
	if(@failtype == 2) goto FAILREMOVECARD2;

FAILREMOVECARD0:
	failedremovecards @part,0;
	misceffect  155;
	next;
	mes @npc_name$;
	mes "Creo que se me paso la mano con la fuerza.";
	mes "Tanto item, como cartas se hicieron añicos, lo siento.";
	emotion e_swt;
	close;

FAILREMOVECARD1:
	failedremovecards @part,1;
	misceffect  154;
	next;
	mes @npc_name$;
	mes "Tu equipo esta perfectamente limpio de cartas ahora.";
	emotion e_gg;
	mes "Sus pedazos arderan en mi hoguera je je";
	close;

FAILREMOVECARD2:
	failedremovecards @part,2;
	misceffect  154;
	next;
	mes @npc_name$;
	mes "No tuve problema para recuperar tus cartas.";
	emotion	e_gg;
	mes "¡Que desperdicio romper tan fino equipo para recuperar esos pedazos de papel!";
	close;

FAILREMOVECARD3:
	failedremovecards @part,3;
	misceffect  101;
	next;
	mes @npc_name$;
	mes "Este equipo se puso dificil de trabajar. No pude hacer nada con el equipo ni con las cartas.";
	close;
	
DENYCARDCOUNT:
	mes @npc_name$;
	mes "¡Pero si este equipo no tiene cartas!";
	close;

Lninguno:
mes @npc_name$;
mes "Estare aqui por si cambias de opinion";
close;
}